大智慧公式网收录大智慧公式,大智慧公式源码.域名http://www.yaoyaoyuan.cn
所在的位置: 大智慧公式网 > 公式编写 > 正文

公式源码:倚天财经公式编辑指南--画图函数(画图)

2011-03-07 04:59:52 选股公式编写,股票公式编写
摘要: STICKLINE(C>0,0,90,6,0),COLOR373829;{公式源码网选编}STICKLINE(C>0,90,100,6,0),COLOR000068;0,POINTDOT;个股资金指数:EMA(((100 * (CLOSE - LLV(LOW,17))) / (HHV(HIGH,17) - LLV(LOW,17))),3);DRAWBAND(个股资金指数>20 ,RGB(0,24,224),个股资金指数,RGB(5,96,96));STICKLINE(C>0,0,20,8,0),COLOR000068;STICK...主图,副图,函数,公式,位置倚天财经公式编辑指南--画图函数画图 公式 函数 编辑 指南画图函数画图函数本组函数的功能是在主图或副图上设定条件输出图象、图标、直线、文字、数字、指标线、指标柱等,全部可以单独使用。个人感觉,倚天的强大功能,在此组函数中有淋漓尽致的发挥。无论在表面(美感),还是实质(提高工作效率)上,都有良好表现。毫无例外的是,这组函数中,都带有COND。CONDITION,条件,状态。COND在这里可作为条件理解。为了能找到合适的COND,用于举例子,请允许我先介绍一组概念。高点
画图函数 画图函数本组函数的功能是在主图或副图上设定条件输出图象、图标、直线、文字、数字、指标线、指标柱等,全部可以单独使用。
个人感觉,倚天的强大功能,在此组函数中有淋漓尽致的发挥。无论在表面(美感),还是实质(提高工作效率)上,都有良好表现。
毫无例外的是,这组函数中,都带有COND。CONDITION,条件,状态。COND在这里可作为条件理解。
为了能找到合适的COND,用于举例子,请允许我先介绍一组概念。
高点:在2N+1根K线中,中间这根K线的H,要大于等于左右N根K线的H。在N+1根K线中,有等高点出现,取最先出现的。
低点:在2N+1根K线中,中间这根K线的L,要小于等于左右N根K线的L。在N+1根K线中,有等低点出现,取最先出现的。
峰点:高点和低点,合称为峰点。
也为了不让公式一来就过于复杂,先取N为2来做公式。简介到后面,可以看到,N是可以作为峰点公式的参数进行调整的。
公式名称:FENG2
公式说明:供引用
公式内容:
{峰点参数暂定为2}
A:=REF(H,2);{中间K线的最高价}
B:=A>=REF(H,4) AND A>=REF(H,3) AND A>=REF(H,1) AND A>=H;{中间K线的最高价大于等于两边共四根K线的最高价}
D:=BACKSET(B,3);{将当前位置和之前2个周期的数值设为1}
HD:FILTER(D,2);{找到高点后,过滤掉其后2周期内可能出现的等高点。输出高点}
A2:=REF(L,2);{中间K线的最低价}
B2:=A2<=REF(L,4) AND A2<=REF(L,3) AND A2<=REF(L,1) AND A2<=L;{中间K线的最低价小于等于两边共四根K线的最低价}
D2:=BACKSET(B2,3);{将当前位置和之前2个周期的数值设为1}
LD:FILTER(D2,2);{找到低点后,过滤掉其后2周期内可能出现的等低点。输出低点}
{后面有些例子,就从这个公式中引用信号。}
函数:DRAWICON
参数: 无
用法: DRAWICON(COND,PRICE,TYPE),当COND条件满足时,在PRICE位置画TYPE号图标。
说明: 在图形上绘制小图标,其中TYPE可选7种图标,编码为1-7(1-3为小脸,4、5为上下箭头,6、7为红绿小旗)。示例: DRAWICON(CLOSE>OPEN,LOW,1);表示当收阳时在最低价位置画1号图
   
1、COND条件,一般是指判断的结果,不是0就是1。如用其它数据,大于等于1的,条件满足;小于1,条件就不满足。
2、TYPE图标,现在已经有12种,用下面的公式,在000829上可以全部显示出来。当TYPE取大于等于12的数时,都显示黄球。
当TYPE取0时,显示的是笑脸(这个公式中没有做进去,自己可以试一下)。
B:="FENG2.HD";
D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
A:=D>REF(D,1);
DRAWICON(REF(A,1),1.05*H,1);
DRAWICON(REF(A,2),1.05*H,2);
DRAWICON(REF(A,3),1.05*H,3);
DRAWICON(REF(A,4),1.05*H,4);
DRAWICON(REF(A,5),1.05*H,5);
DRAWICON(REF(A,6),1.05*H,6);
DRAWICON(REF(A,7),1.05*H,7);
DRAWICON(REF(A,8),1.05*H,8);
DRAWICON(REF(A,9),1.05*H,9);
DRAWICON(REF(A,10),1.05*H,10);
DRAWICON(REF(A,11),1.05*H,11);
DRAWICON(REF(A,12),1.05*H,12);
DRAWICON(REF(A,13),1.05*H,13);
DRAWICON(REF(A,14),1.05*H,100);{主图叠加}

当红球和绿球连续显示时,立体感会强一些。
DRAWICON(C>=MA(C,30),MA(C,30),10);
DRAWICON(C<MA(C,30),MA(C,30),11);{主图叠加}
3、PRICE是用于定位图标的位置的。一般用1.01*H,或者0.99*L等。现在可用ALIGN(0-5)指定对齐位置。
用这个公式来试(主图叠加)
B:="FENG2.HD";
D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
A:=D>REF(D,1);
E:=REF(H,1);
DRAWICON(A,E,10),ALIGN0;
DRAWICON(A,E,11),ALIGN1;
DRAWICON(A,E,12),ALIGN2;
DRAWICON(A,E,3),ALIGN3;
DRAWICON(A,E,4),ALIGN4;
DRAWICON(A,E,5),ALIGN5;
可以初步得出结论:
ALIGN0:信号出现在PRICE的正中;
ALIGN1:信号出现在PRICE下边(十分靠近);
ALIGN2:信号出现在PRICE上边(十分靠近);
ALIGN3:信号出现在主图的中间;
ALIGN4:信号出现在主图的最上边;
ALIGN5:信号出现在主图的最下边;

在高低点上作图标,可以使高低点更明确了。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;{主图叠加}

例如:
DRAWICON(CLOSE>OPEN,LOW,1);
DRAWICON(OPEN>CLOSE,high,2);
DRAWICON(CLOSE>OPEN,close,3);
DRAWICON(OPEN>CLOSE,open,4);
DRAWICON(CLOSE>OPEN,LOW,5);
DRAWICON(OPEN>CLOSE,high,6);
DRAWICON(OPEN>CLOSE,high,7);



函数:DRAWLINE
参数: 无
用法: DRAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND),当COND1条件满足时,在PRICE1位置画直线起点,当COND2条件满足时,在PRICE2位置画直线终点,EXPAND为延长类型。
说明: 在图形上绘制直线段。
示例: DRAWILINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1);表示在创20天新高与创20天新低之间画直线并且向右延长。
DRAWLINE是唯一一个一句里面用到两个COND的绘图函数。因为它需要两个点来决定一直线。
COND1相当于指定K线位置(横坐标),PRICE1相当于是指定价位(纵坐标),这样一个点在平面上的位置就决定了。
DRAWLINE是从第一点画到第二点的,即有起点与终点的顺序关系:第一点出现的时间,要在第二点之前。否则线是画不出来的。
EXPAND,扩张、发展,这里是延伸的意思吧。一般取0,不延长;取1,延长。实际上是取大于等于1的数就延长,小于1就不延长。
DRAWLINE目前支持POINTDOT、LINETHICK、COLOR、SHIFT这四个描述函数。



函数:DRAWTEXT
参数: 无
用法: DRAWTEXT(COND,PRICE,TEXT),当COND条件满足时,在PRICE位置书写文字TEXT,可显示多行文本,用"\n"换行。
说明: 在图形上显示文字。
示例: DRAWTEXT(CLOSE/OPEN>1.08,LOW,'大阳线');表示当日涨幅大于8%时在最低价位置显示'大阳线'字样。
DRAWTEXT(CLOSE/OPEN>1.08,LOW,'好呀\n大涨啦');可显示多行文本,用"\n"换行;



函数:POLYLINE
参数: 无
用法: POLYLINE(COND,PRICE),当COND条件满足时,以PRICE位置为顶点画折线连接。
说明: 在图形上绘制折线段。
示例: POLYLINE(HIGH>=HHV(HIGH,20),HIGH);表示在创20天新高点之间画折线。
POLY,多个的。
支持POINTDOT、LINETHICK、COLOR、SHIFT这四个描述函数。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;
POLYLINE(A,L),POINTDOT,COLORGREEN;
POLYLINE(B,H),LINETHICK2,COLORMAGENTA;{主图叠加}



函数:STICKLINE
参数: 无
用法: STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),当COND条件满足时,在PRICE1和PRICE2位置之间画柱状线,宽度为WIDTH可为0---100(10为标准间距),EMPTH不为0则画空心柱。
说明: 在图形上绘制柱线。
示例: STICKLINE(CLOSE>OPEN,CLOSE,OPEN,0.8,1);表示画K线中阳线的空心柱体部分。

再说明三点:
1、PRICE1和PRICE2没有顺序关系,即何者在前何者在后都不影响语句的执行。
2、WIDTH宽度,支持小数。用1和用0.1,会有很大的差别。取7时和主图的K线宽度差不多。
以下的副图公式,画出的K线,与主图中显示的K线差不多。有些“主图叠加公式”,叠加在副图中也未尝不可了。
STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,7,1),colorred;{画出红K实体}
STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{画出红K上影线}
STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{画出红K下影线}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,7,0),colorcyan;{画出青K实体}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorcyan;{画出青K影线。因为青K是实心的,所以影线从中穿过}
MA(C,5);
3、用STICKLINE可以用两种方法做出多色彩K线效果。
一种是横向的,将K线实体从O到C分为N等份,每个小格中放入不同的但比较连续的颜色。
这里随便举个例子,N取4,只对阳线加了效果。其它变化,道理是一样的。
A:=C-O;
B:=C>O;
STICKLINE(B,O,O+A/4,8,0),COLORFF99FF;
STICKLINE(B,O+A/4,O+A*2/4,8,0),COLORFF00FF;
STICKLINE(B,O+A*2/4,O+A*3/4,8,0),COLOR9900FF;
STICKLINE(B,O+A*3/4,O+A,8,0),COLOR0000FF;{主图叠加}
还有一种方法就是纵向的了。先在较宽的K线中加颜色,然后把宽度逐步收窄,再加颜色覆盖以前的的,这样从纵向看,一根K线中就有不同颜色了。效果做得好的,可以做到赏心悦目。
B:=C>O;
STICKLINE(B,O,C,8,0),COLORFF99FF;
STICKLINE(B,O,C,6,0),COLORFF00FF;
STICKLINE(B,O,C,4,0),COLOR9900FF;
STICKLINE(B,O,C,2,0),COLOR0000FF;{主图叠加}



函数:DRAWNUMBER(COND,PRICE,NUMBER,PRECISION)
参数: NUMBER(可以为常数或数组序列),PRECISION为精度(取值范围0-3),即显示到小数点后PRECISION位。
用法: DRAWNUMBER(COND,PRICE,NUMBER,PRECISION),当COND条件满足时,在PRICE位置书写数字
说明: 在图形上显示数字。
示例: DRAWNUMBER(CLOSE/OPEN>1.08,HIGH,(CLOSE-OPEN)/OPEN*100,2);表示当日涨幅大于8%时在最低价位置显示涨幅(相对开盘价的百分比)。


 {点击看本软件截图:分.析家公 式网 http://www、gongshi8、com 整理}

  声明:本站部分内容来自合作媒体及网络,不代表本站观点。本站不对上述言论承担责任。关键字:主图,副图,函数,公式,位置
相关阅读:
  • >>公式-通达信强弓之末天地量比逃顶指标公式主图源码(主图)
    买好股公式文章通达信强弓之末天地量比逃顶指标公式主图源码,介绍地量,逃顶,公式,主图,源码炒股技巧,让您在股市里买到好股票。{同花顺公式网选编}首发一个本人原创的逃顶指标:天量地量之比>30倍时逃顶。注意:这个条件不是每个顶都合适,...
  • >>[指标]同花顺主力力道抄底指标利好趋势投资者指标公式(同花顺)
    买好股公式文章同花顺主力力道抄底指标利好趋势投资者指标公式,介绍抄底,主力力道,趋势投资者炒股技巧,让您在股市里买到好股票。该指标反应了资金的动向,简单的说就是主力和散户。当主力线从低位上穿散户线时卖出,当主力线在高位背离时...
  • >>指标源码:通达信三碗不过岗抄底副图公式源码(副图)
    该指标在绿色的位置时不可以买入的,要等到咱们缸里的水满了后才是可以买入的信号,也就是黄色的位置,大家一定要记住了,当指标颜色一直为白色的时候就说明该股是可以持有的,当白色逐渐缩短并变为蓝色的时候是卖出股票的时候VAR2:=(CLO...
  • 关键字: